# This program is free software: you can redistribute it and/or modify

# it under the terms of the GNU General Public License as published by

# the Free Software Foundation, either version 3 of the License, or

# (at your option) any later version.

#

# This program is distributed in the hope that it will be useful,

# but WITHOUT ANY WARRANTY; without even the implied warranty of

# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

# GNU General Public License for more details.

#

# You should have received a copy of the GNU General Public License

# along with this program.  If not, see <http://www.gnu.org/licenses/>.

package CrashTest::Storage::Sql;

use Mojo::Base "CrashTest::Storage::FileSystem";

use DateTime;

use CrashTest::Storage::Sql::Schema;

sub new {

    my $self = shift->SUPER::new(@_);

    $self->{schema} = CrashTest::Storage::Sql::Schema->connect($self->config->{DSN});

    return $self;

}

sub index {

    my ($self, $page, $nperpage) = @_;

    my $dbcrashs = $self->{schema}->resultset('CrashReport')->search(

        undef,

        {

            prefetch    => [ 'product', 'crash_user' ],

            order_by    => { -desc => 'crash_time' },

            page        => $page,

            rows        => $nperpage,

        },

    );

    my $results = {

        pager   => $dbcrashs->pager,

        crashs  => [],

    };

    for my $crash($dbcrashs->all) {

        my $filename = File::Spec->catfile($self->{data_path}, $crash->uuid);

        push @{$results->{crashs}}, {

            file        => $filename,

            uuid        => $crash->uuid,

            product     => $crash->product->name,

            version     => $crash->product->version,

            user        => $crash->crash_user->user_id,

            date        => $crash->crash_time,

        }

    }

    return $results;

}

sub _db_insert_processed_data {

    my ($self, $uuid, $pjson) = @_;

    $self->{schema}->txn_do(sub {

        my $crash = $self->{schema}->resultset('CrashReport')->new({ uuid => $uuid });

        if($pjson->{client_info}->{StartupTime}) {

            $crash->start_time(DateTime->from_epoch(epoch => $pjson->{client_info}->{StartupTime}));

        }

        if($pjson->{client_info}->{CrashTime}) {

            $crash->crash_time(DateTime->from_epoch(epoch => $pjson->{client_info}->{CrashTime}));

        }

        my $product = {

            distributor => $pjson->{client_info}->{Distributor},

            name        => $pjson->{client_info}->{ProductName},

            version     => $pjson->{client_info}->{Version},

        };

        my $dbproduct = $self->{schema}->resultset('Product')->search($product)->first();

        if($dbproduct) {

            $crash->product($dbproduct);

        } else {

            $product->{release_channel} = $pjson->{client_info}->{ReleaseChannel};

            $crash->product($self->{schema}->resultset('Product')->new($product));

        }

        my $user = {

            user_id => $pjson->{client_info}->{UserID},

        };

        my $dbuser = $self->{schema}->resultset('CrashUser')->search($user)->first();

        if($dbuser) {

            $crash->crash_user($dbuser);

        } else {

            $user->{cpu_arch}   = $pjson->{system_info}->{cpu_arch};

            $user->{cpu_count}  = $pjson->{system_info}->{cpu_count};

            $user->{os}         = $pjson->{system_info}->{os};

            $crash->crash_user($self->{schema}->resultset('CrashUser')->new($user));

        }

        # TODO crash_threads => [ ],

        $crash->insert;

    });

}

sub store_processed_data {

    my ($self, $uuid, $pjson) = @_;

    $self->SUPER::store_processed_data($uuid, $pjson);

    $self->_db_insert_processed_data($uuid, $pjson);

}

1;