# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

package CrashTest::Plugin::Storage::Sql::Model::CrashReport;

use Mojo::Base -base;
use Mojo::JSON::MaybeXS;
use Mojo::JSON qw/encode_json decode_json/;
use DateTime;
use Data::Page;
#use DBI::Log;
#$DBI::Log::trace = 0;

use CrashTest::Plugin::Storage::Sql::Model::CrashGroup;
use CrashTest::Plugin::Storage::Sql::Utils;

has [ qw/instance app config/ ];

has [ qw/dbh sql_utils crash_groups/ ];

sub new {
    my $self = shift->SUPER::new(@_);

    $self->dbh($self->instance->dbh);
    $self->sql_utils(CrashTest::Plugin::Storage::Sql::Utils->new(@_));
    $self->crash_groups(CrashTest::Plugin::Storage::Sql::Model::CrashGroup->new(@_));

    return $self;
}

sub db {
    my ($self) = @_;
    return $self->dbh->db;
}

sub _build_query_from_search_string {
    my ($self, $search_str) = @_;
    return $self->sql_utils->build_query_from_search_string(
        $search_str,
        $self->app->config->{WebInterface}->{ExtraColumns}->{Search}, {
            user_id     => { name => 'crash_user.user_id' },
            product     => { name => 'product.name' },
            version     => { name => 'product.version' },
            channel     => { name => 'product.release_channel' },
            group_id    => { name => 'crash_reports.crash_group_id' },
            function    => { name => 'crash_group.crash_thread_signature_bt', type => "fuzzy" },
            bug         => { name => 'crash_reports.crash_group_id IN (SELECT crash_group_id FROM bug_links WHERE bug_key ?op? ?)', type => 'sql' },
        });
}

sub index {
    my ($self, $pagen, $nperpage, $search_str) = @_;

    my $db = $self->db;

    my $where = "";
    my @values = ();
    my $err;
    if(defined($search_str) && $search_str ne "") {
        eval {
            my $q = $self->_build_query_from_search_string($search_str);
            $where = "WHERE " . $q->[0];
            @values = @{$q->[1]};
        };
        $err = $@;
    }

    my $count = $db->query("
        SELECT count(crash_reports.id) AS total FROM crash_reports
        LEFT JOIN crash_users AS crash_user ON crash_reports.crash_user_id = crash_user.id
        LEFT JOIN products AS product ON crash_reports.product_id = product.id
        LEFT JOIN crash_groups AS crash_group ON crash_reports.crash_group_id = crash_group.id
        $where
        ", @values)->hash;

    my $pager = Data::Page->new();
    $pager->total_entries($count->{total});
    $pager->entries_per_page($nperpage);
    $pager->current_page($pagen);

    my @extra_cols;
    foreach my $extra_col(@{$self->app->config->{WebInterface}->{ExtraColumns}->{Index}}) {
        push @extra_cols, $extra_col->{db_column} . " AS " . $extra_col->{id};
    }
    my $extra_columns = join(",", @extra_cols);

    my $results = $db->query("
        SELECT  crash_reports.*,
                product.distributor AS p_distributor, product.name AS p_name, product.version AS p_version, product.release_channel AS p_release_channel,
                crash_user.os AS u_os, crash_user.cpu_arch AS u_cpu_arch, crash_user.cpu_count AS u_cpu_count, crash_user.extra_info AS u_extra_info,
                (SELECT json_agg(to_json(bug_links)) FROM bug_links WHERE bug_links.crash_group_id = crash_reports.crash_group_id) AS bug_links,
                $extra_columns
        FROM crash_reports
        LEFT JOIN crash_users AS crash_user ON crash_reports.crash_user_id = crash_user.id
        LEFT JOIN products AS product ON crash_reports.product_id = product.id
        LEFT JOIN crash_groups AS crash_group ON crash_reports.crash_group_id = crash_group.id
        $where
        ORDER BY crash_time DESC
        OFFSET (?) ROWS
        FETCH NEXT (?) ROWS ONLY
        ",
        @values,
        $pager->skipped, $pager->entries_per_page
    )->expand->hashes;

    return ($results, $pager, $err);
}

sub get {
    my ($self, $uuid) = @_;

    my $db = $self->db;

    my @extra_cols;
    foreach my $extra_col(@{$self->app->config->{WebInterface}->{ExtraColumns}->{Index}}) {
        push @extra_cols, $extra_col->{db_column} . " AS " . $extra_col->{id};
    }
    my $extra_columns = join(",", @extra_cols);

    my $result = $db->query("
        SELECT  crash_reports.*,
                product.distributor AS p_distributor, product.name AS p_name, product.version AS p_version, product.release_channel AS p_release_channel,
                crash_user.os AS u_os, crash_user.cpu_arch AS u_cpu_arch, crash_user.cpu_count AS u_cpu_count, crash_user.extra_info AS u_extra_info,
                (SELECT json_agg(to_json(bug_links)) FROM bug_links WHERE bug_links.crash_group_id = crash_reports.crash_group_id) AS bug_links,
                $extra_columns
        FROM crash_reports
        LEFT JOIN crash_users AS crash_user ON crash_reports.crash_user_id = crash_user.id
        LEFT JOIN products AS product ON crash_reports.product_id = product.id
        LEFT JOIN crash_groups AS crash_group ON crash_reports.crash_group_id = crash_group.id
        WHERE crash_reports.uuid = ?
        ",
        $uuid
    )->expand->hash;

    return $result;
}

sub get_processed_data {
    my ($self, $uuid) = @_;

    my $db = $self->db;

    my $dbdata = $db->query("SELECT processed FROM crash_report_datas WHERE crash_report_id = (SELECT id FROM crash_reports WHERE uuid = ?)", $uuid)->hash;

    my $processed_data = decode_json($dbdata->{processed});

    return $processed_data;
}

sub create {
    my ($self, $uuid, $pjson, $client_info, $dmp_file) = @_;

    my $db = $self->db;

    if(!defined($client_info->{UserID})) {
        $self->app->log->info("Invalid crash $uuid: no UserID");
        return;
    }

    my $tx = $db->begin;

    my ($start_time, $crash_time);
    if($client_info->{StartupTime}) {
        $start_time = DateTime->from_epoch(epoch => $client_info->{StartupTime});
    }
    if($client_info->{CrashTime}) {
        $crash_time = DateTime->from_epoch(epoch => $client_info->{CrashTime});
    } elsif($start_time) {
        $crash_time = $start_time;
    } else {
        $crash_time = DateTime->from_epoch(epoch => time());
    }

    chomp($client_info->{ProductName});
    chomp($client_info->{Version}) if $client_info->{Version};
    my @product_values = (
        $client_info->{Distributor},
        $client_info->{ProductName},
        $client_info->{Version},
    );

    my $dbproduct = $db->query("SELECT * FROM products WHERE distributor = ? AND name = ? AND version = ?", @product_values)->hash;
    if(!$dbproduct) {
        push @product_values, $client_info->{ReleaseChannel};
        $dbproduct = $db->query(
            "INSERT INTO products (distributor, name, version, release_channel) VALUES (?, ?, ?, ?) RETURNING *",
            @product_values
        )->hash;
    }

    my @user_values = (
        $client_info->{UserID},
    );

    my $dbuser = $db->query("SELECT * FROM crash_users WHERE user_id = ?", @user_values)->hash;
    if(!$dbuser) {
        push @user_values, $pjson->{system_info}->{cpu_arch};
        push @user_values, $pjson->{system_info}->{cpu_count};
        push @user_values, $pjson->{system_info}->{os};
        push @user_values, encode_json($client_info);

        $dbuser = $db->query(
            "INSERT INTO crash_users (user_id, cpu_arch, cpu_count, os, extra_info) VALUES (?, ?, ?, ?, ?) RETURNING *",
            @user_values
        )->hash;
    }

    my $crash_group = $self->crash_groups->find_or_create($uuid, $pjson, $db);

    my $main_module;
    {
        my $i = $pjson->{main_module};
        $main_module = $pjson->{modules}->[$i]->{filename};
    }

    my $dbcrash = $db->query(
        "INSERT INTO crash_reports (start_time, crash_time, uuid, main_module, product_id, crash_user_id, crash_group_id, crash_group_distance)
         VALUES (?, ?, ?, ?, ?, ?, ?, ?) RETURNING id",
        $start_time, $crash_time, $uuid, $main_module, $dbproduct->{id}, $dbuser->{id},
        $crash_group ? $crash_group->{id} : undef,
        $crash_group ? ($crash_group->{dist} || 0) : undef,
    )->hash;

    # Create json for the params
    $pjson->{client_info} = $client_info;
    $db->query(
        "INSERT INTO crash_report_datas (crash_report_id, processed) VALUES (?, ?) RETURNING id",
        $dbcrash->{id}, encode_json($pjson)
    );

    $tx->commit;

    return $dbcrash->{id};
}

sub update {
    my ($self, $uuid, $pjson, $dmp_file) = @_;

    my $db = $self->db;

    my $tx = $db->begin;

    my $dbcrash = $db->query("SELECT id FROM crash_reports WHERE uuid = ?", $uuid)->hash;

    $db->query("
        UPDATE crash_report_datas SET processed = ?
        WHERE crash_report_id = ?",
        encode_json($pjson),
        $dbcrash->{id},
    );

    $db->query("
        UPDATE crash_reports SET crash_group_id = NULL, crash_group_distance = NULL
        WHERE id = ?",
        $dbcrash->{id},
    );

    $self->crash_groups->delete_unused($db);

    my $crash_group = $self->crash_groups->find_or_create($uuid, $pjson, $db);

    $db->query("
        UPDATE crash_reports SET crash_group_id = ?, crash_group_distance = ?
        WHERE id = ?",
        $crash_group ? $crash_group->{id} : undef,
        $crash_group ? ($crash_group->{dist} || 0) : undef,
        $dbcrash->{id},
    );

    $tx->commit;

    return 1;
}

1;